//Number 24
//Chuck a day 2009
//by Scott Hewitt
//www.ablelemon.co.uk/chuckaday

public class bus
{
    static Gain @ chan[8];
}
new Gain[8] @=> bus.chan;

//labels for sliders
["0","1","2","3","4","5","6","7"] @=> string label[];

MAUI_View bus_view;
bus_view.size( 250, 500 );
    
MAUI_Gauge gauge[8];
MAUI_Slider slider[8];
    
//setup gauge
function void lev_mon (int a){
    while (true){
        bus.chan[a].last() * 100.0 => gauge[a].value;
        20::ms => now;
    }
}
    
    //await slider movment
function void slid_event (int b){
    while (true){
        slider[b] => now;
        slider[b].value() => bus.chan[b].gain;
    }
}
    
    //setup interface for each bus
for(0 => int i; i < 8; i++ ){
    bus_view.addElement (gauge[i]);
    gauge[i].position(0,(i * 60));
    bus_view.addElement (slider[i]);
    label[i] => slider[i].name;
    slider[i].position(0,(i * 60));
    spork ~ lev_mon(i);
    spork ~ slid_event(i);
    0 => bus.chan[i].gain;
}

//draw display    
bus_view.display();

//demo connects
adc => bus.chan[0];
adc => bus.chan[4];

bus.chan[0] => dac;
bus.chan[4] => dac;

while(true) {
    5::second => now;
}