//Number 27
//Chuck a day 2009
//by Scott Hewitt
//www.ablelemon.co.uk/chuckaday

//DSP
adc => Gain ginput => PitShift ps => dac;

Event exitevent;

//GUI
MAUI_View pitgui;

MAUI_Slider pitshift;
MAUI_Slider pitmix;
MAUI_Button exitbutton;
MAUI_Gauge gaugemaster;


pitgui.addElement (gaugemaster);
gaugemaster.position(250,10);

pitshift.position(0,0);
pitmix.position(0,60);
exitbutton.position(300,60);
exitbutton.pushType();
exitbutton.name("Exit");

pitshift.name("Pitch Shift");
pitshift.range(0.5, 1.5);

pitmix.name("Pitch Mix");

pitgui.addElement(exitbutton);
pitgui.addElement(pitshift);
pitgui.addElement(pitmix);

pitgui.size(500, 200);

pitgui.display();

//exit button event
function void exitbutton_event (){
    while (true){
        exitbutton => now;
        exitevent.broadcast();
    }
}

function void shift_event(){
    while (true){
        pitshift => now;
        pitshift.value() => ps.shift;
    }
}

function void mix_event(){
    while (true)
    {
        pitmix => now;
        pitmix.value() => ps.mix;
    }
}

function void lev_mon(){
    while (true){
        ginput.last() * 100.0 => gaugemaster.value;
        20::ms => now;
    }
}

//sporks
spork ~ lev_mon();   
spork ~ exitbutton_event();   
spork ~ shift_event();
spork ~ mix_event();

exitevent => now;
<<<"Pitch Shift Exit">>>;

me.exit();